Como CRIAR um bloco com ENTMAKE

CRIAR um bloco via autolisp pode não ser muito fácil e muitos já me perguntaram como se faz... então lá vai:

;PRIMEIRO!
;sempre que for CRIAR o bloco, use estas linhas PRIMEIRO
(entmake '((0 . "BLOCK")         ;tipo de entidade
       (2 . "nome_do_bloco") ;nome do bloco
       (8 . "0")             ;layer
       (10 0.0 0.0 0.0)      ;ponto de base
;|se o bloco tem atributos editaveis use 2,
  se nao te atributos, use 0
  veja o help para mais opções|;
       (70 . 2)            
      ))

;AGORTA CRIA ENTIDADES NORMALMENTE...
;exemplo: uma linha:
(entmake '((0 . "LINE")
       (8 . "0")
       (10 0.0 0.0 0.0)
       (11 10.0 0.0 0.0)
      )
)
;COMO SE CRIA UM ATRIBUTO:
;se vc usou o dxf 70 iguala 2, o bloco tem atributos
;logo, vc precisa criar eles
;use uma sequencia desta para cada atributo que voce quer criar:
(entmake '((0 . "ATTDEF") ;tipo de entidade: atributo
       (8 . "0")                  ;layer
       (10 1.0 1.0 0.0)           ;ponto de inserção
       (40 . 2)                   ;altura do texto
       (1 . "defval")             ;valor padrão
       (50 . 0)                   ;rotação
       (7 . "standard")           ;estilo do texto
       (72 . 1)                   ;alinhamento horizontal
;alinhamento do texto, se o dxf 72 e 74 são diferentes de zero
;vc precisará dele...
       (11 1.0 1.0 0.0)
       (3 . "Entre com o valor")  ;prompt na linha de comando
       (2 . "nome_da_tag")        ;nome do atributo
       (70 . 0)                   ;veja o help para as opções
       (74 . 0)                   ;alinhamento vertical
      )
)

;sempre finalizamos a criação do bloco com uma entidade ENDBLOCK:
(entmake '((0 . "ENDBLK")))        ;POR ÚLTIMO!
;e assim CRIAMOS o bloco...

Logo postarei um exemplo de como INSERIR este bloco com o ENTMAKE... não se esqueça que INSERIR é diferente de CRIAR um bloco